|  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  | A | B | C | D | E | F | G | H | I | J | K |
| 1 | Naziv | Količina | Nabavna cijena | Marža | Poreska kategorija | PDV | MP Cijena | Ukupna nabavna vrijednost | Ukupna marža | Ukupni PDV | Ukupna MP vrijednost |
| 2 | Monitor | 6 | 155.00 | 10.85 | A | 28.19 | 194.04 | 930.00 | 65.10 | 169.17 | 1164.27 |
| 3 | Miš | 30 | 4.35 | 0.09 | B | 0.67 | 5.10 | 130.50 | 2.61 | 19.97 | 153.08 |
| 4 | Tastatura | 27 | 8.65 | 0.17 | B | 1.32 | 10.15 | 233.55 | 4.67 | 35.73 | 273.95 |
| 5 | Papir (ris) | 50 | 3.80 | 0.08 | C | 0.27 | 4.15 | 190.00 | 3.80 | 13.57 | 207.37 |
| 6 | Štampač | 6 | 360.00 | 25.20 | A | 65.48 | 450.68 | 2160.00 | 151.20 | 392.90 | 2704.10 |
| 7 | MS Windows XP Home edition | 20 | 99.00 | 4.95 | C | 7.28 | 111.23 | 1980.00 | 99.00 | 145.53 | 2224.53 |
| 8 | MS Office XP | 15 | 499.00 | 34.93 | C | 37.38 | 571.31 | 7485.00 | 523.95 | 560.63 | 8569.58 |
| 9 | Podloga za miša | 50 | 1.00 | 0.02 | D | 0.00 | 1.02 | 50.00 | 1.00 | 0.00 | 51.00 |
| 10 |  |  |  |  |  |  |  |  |  |  |  |
| 11 |  |  |  |  |  |  | **Ukupno:** | **13159.05** | **851.33** | **1337.49** | **15347.87** |

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
|  | C | D | E | F |
| 13 | Poreske stope | | Ukupni PDV | Broj proizvoda |
| 14 | Kategorija | Porez |
| 15 | A | 17% | 562.07 | 2 |
| 16 | B | 15% | 55.70 | 2 |
| 17 | C | 7% | 719.72 | 3 |
| 18 | D | 0% | 0.00 | 1 |

**Zadatak:** Formirati tabelu u Excel-u koja služi za evidenciju proizvoda na lageru jedne male firme. Sva osjenčena polja su vrijednosti koje se unose u tabelu, neosjenčena polja su vrijednosti koje treba izračunati prema sledećim pravilima:

1. Marža se računa kao 2% od nabavne cijene za proizvode kod kojih je nabavna cijena manja od 20 €, 5% za nabavnu cijenu od 20 do 100 € i 7% ako je nabavna cijena veća od 100€.
2. PDV se računa na osnovu poreske kategorije (kolona E) i pomoćne tabele (C13:D18) u kojoj su za svaku kategoriju unešene poreske stope. Osnovica za računanje PDV-a je nabavna cijena uvećana za maržu.
3. Maloprodajna (MP) cijena se računa tako što se na nabavnu cijenu dodaju marža i PDV.
4. Ukupna nabavna vrijednost, ukupna marža, ukupni PDV i ukupna MP vrijednost se računaju tako što se odgovarajući pojedinačni iznosi pomnože se količinom proizvoda.
5. U ćelijama H11 do K11 je izračunat ukupni zbir odgovarajućih kolona.
6. U ćelijama E15 do E18 izračunat je zbir ukupnog PDV-a (kolona J) za svaku od poreskih kategorija zasebno, dok je u ćelijama F15 do F18 broj proizvoda u odgovarajućoj poreskoj kategoriji.
7. Grafički prikazati količinu pojedinih proizvoda (na x-osi se ispisuje naziv proizvoda a y-osa je količina tog proizvoda).

**Rješenje zadatka:**

1. Ukucajte sve osjenčene vrijednosti vodeći računa da vrsta i kolona vaše tabele u Excel-u odgovaraju vrsti i koloni u primjeru.
2. Marža: U ćeliju D2 otkucajte formulu: **=C2\*IF(C2<20,2%,IF(C2<100,5%,7%))** i formulu iskopirajte u ćelije D3, D4, ... do D9.
3. PDV: U ćeliju F2 otkucajte formulu: **=(C2+D2)\*VLOOKUP(E2,C$15:D$18,2)** Ovdje se koristi VLOOKUP funkcija da u pomoćnoj tabeli C$15:D$18 nađe podatak o poreskoj stopi za željenu kategoriju. Uočite da je poreska stopa u drugoj koloni pomoćne tabele. Simbol $ je iskorišćen da pri kopiranju formule u ćelije F3, F4, ... do F9 adresa pomoćne tabele ostane nepromijenjena.
4. MP cijena: U ćeliju G2 otkucajte formulu: **=C2+D2+F2**
5. Ukupne vrijednosti: U ćelije H2, I2, J2 i K2 ukucajte formule: **=C2\*B2 , =D2\*B2 , =F2\*B2 i =B2\*G2**
6. Iskopirajte formule iz drugog reda u 3., 4. ... i 9. red za kolone G, H, I, J i K.
7. Ukupne zbirove računajte tako što u ćeliju H11 ukucate formulu: **=SUM(H2:H9)** i tu formulu iskopirate u ćelije I11, J11 i K11.
8. Porez po kategorijama, u pomoćnoj tabeli, možemo sračunati formulom: **=SUMIF(E$2:E$9,"=" & C15,J$2:J$9)** u ćeliji E15 i kopiranjem formule u ćelije E16, E17 i E18. Kod ove formule vršimo sabiranje vrijednosti PDV-a (kolona J osnovne tabele), pri čemu je kriterijum sabiranja poreska kategorija (kolona E osnovne tabele). Uočite način formiranja kriterijuma: "=" & C15 znači da se na simbol = nadoveže podatak iz ćelije C15 (kategorija A) tako da se kriterijum u prvom slučaju svodi na "=A", u drugom na "=B"... Ovaj dio zadatka mogao se riješiti i kucanjem četiri formule oblika =SUMIF(E2:E9,"=A",J2:J9), =SUMIF(E2:E9,"=B",J2:J9) ... u odgovarajuće ćelije (uočite da sada simbol $ nije neophodan jer ne kopiramo formule već svaku treba pojedinačno unijeti).
9. Broj proizvoda određujemo formulom **=COUNTIF(E$2:E$9,"="&C15)** gdje važi isto zaključivanje vezano za kriterijum kao u prethodnoj tački.
10. Nakon što su svi podaci unešeni u tabelu, tabelu treba grafički urediti tako da podaci budu pregledni. Koristite se poravnanjima, fiksiranjem broja decimala, linijama okvira i bojama pozadine. Ćelije C13 i D13 su spojene (merged), kao i ćelije E13 i E14, odnosno F13 i F14. Ćelije zaglavlja osnovne tabele su formatirane tako da se tekst lomi u više redova i da se ispisuje po sredini ćelije što podešavate pomoću Format menija stavke Cells u dijelu Allignment stavkama Horizontal, Vertical i Wrap text.